sub:assertion {
  sub:get-taxontaxon-nanopubs dct:description "This query returns all taxon-taxon relations according to the BioLink schema." ;
    dct:license <http://www.apache.org/licenses/LICENSE-2.0> ;
    a <https://w3id.org/kpxl/grlc/grlc-query> ;
    rdfs:label "Get all taxon-taxon relation nanopublications" ;
    <https://w3id.org/kpxl/grlc/endpoint> <https://w3id.org/np/l/nanopub-query-1.1/repo/type/fd13bf88327b03b2d2113782d657a93d44e58b527a05820be731ff75a42fabb4> ;
    <https://w3id.org/kpxl/grlc/sparql> """prefix np: <http://www.nanopub.org/nschema#>
prefix npa: <http://purl.org/nanopub/admin/>
prefix npx: <http://purl.org/nanopub/x/>
prefix xsd: <http://www.w3.org/2001/XMLSchema#>
prefix dct: <http://purl.org/dc/terms/>
prefix biolink: <https://w3id.org/biolink/vocab/>
prefix nt: <https://w3id.org/np/o/ntemplate/>
prefix biodiv: <https://w3id.org/kpxl/biodiv/terms/>
prefix prov: <http://www.w3.org/ns/prov#>
prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>

select distinct ?np ?label ?subjtaxonname ?subjtaxonlabel ?rel ?objtaxonname ?objtaxonlabel ?source ?date where {
  graph npa:graph {
    ?np npx:hasNanopubType biolink:OrganismTaxonToOrganismTaxonAssociation .
    ?np npa:hasValidSignatureForPublicKeyHash ?pubkey .
    filter not exists { ?npx npx:invalidates ?np ; npa:hasValidSignatureForPublicKeyHash ?pubkey . }
    ?np dct:created ?date .
    ?np np:hasAssertion ?a .
    ?np np:hasProvenance ?p .
    ?np np:hasPublicationInfo ?i .
    optional { ?np rdfs:label ?label }
  }
  graph ?a {
    ?association a biolink:OrganismTaxonToOrganismTaxonAssociation .
    ?association biolink:subject ?subjtaxon .
    ?subjtaxon biodiv:hasTaxonName ?subjtaxonname .
    ?association biolink:predicate ?rel .
    ?association biolink:object ?objtaxon .
    ?objtaxon biodiv:hasTaxonName ?objtaxonname .
  }
  graph <http://purl.org/np/RAVTdAMPj7oOfekUVyIcrXX9HheGa_0QCC5-PK7Di8DPg/assertion> {
    ?rel rdfs:label ?rellabel .
  }
  optional {
    graph ?p {
      ?a prov:wasDerivedFrom ?source
    }
  }
  graph ?i {
    optional { ?subjtaxonname nt:hasLabelFromApi ?subjtaxonlabel . }
    optional { ?objtaxonname nt:hasLabelFromApi ?objtaxonlabel . }
  }
}
order by desc(?date)""" .
}