sub:assertion {
  sub:get-ro-crates dct:description "This query returns all RO-Crates of which the metadata were published as nanopublications." ;
    dct:license <http://www.apache.org/licenses/LICENSE-2.0> ;
    a <https://w3id.org/kpxl/grlc/grlc-query> ;
    rdfs:label "Get RO-Crates" ;
    <https://w3id.org/kpxl/grlc/endpoint> <https://w3id.org/np/l/nanopub-query-1.1/repo/type/a94355158beda26c5d1533e079a7f76e827b9037dc594fac440e0cf3a2a153d1> ;
    <https://w3id.org/kpxl/grlc/sparql> """PREFIX schema: <http://schema.org/>
prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix dct: <http://purl.org/dc/terms/>
prefix np: <http://www.nanopub.org/nschema#>
prefix npa: <http://purl.org/nanopub/admin/>
prefix npx: <http://purl.org/nanopub/x/>

select distinct ?np ?metadata ?obj (group_concat(distinct ?objType; separator=\" \") as ?objTypes) (group_concat(distinct ?keyword; separator=\" \") as ?keywords) ?date where {
  graph npa:graph {
    ?np npa:hasValidSignatureForPublicKey ?pubkey .
    filter not exists { ?npx npx:invalidates ?np ; npa:hasValidSignatureForPublicKey ?pubkey . }
    ?np np:hasAssertion ?a .
    optional { ?np rdfs:label ?label }
  }
  graph ?a {
    optional { ?metadata_a <http://schema.org/about> ?obj_a . filter(strends(str(?metadata_a), \"ro-crate-metadata.json\")) }
    optional { ?metadata_b <http://schema.org/about> ?obj_b . filter(strends(str(?metadata_b), \"ro-crate-metadata.jsonld\")) }
    filter(bound(?metadata_a) || bound(?metadata_b))
    bind(coalesce(?metadata_a, ?metadata_b) as ?metadata)
    bind(coalesce(?obj_a, ?obj_b) as ?obj)
  }
  optional { graph ?a { ?obj schema:datePublished ?datePublished . } }
  optional { graph ?a { ?obj schema:dateCreated ?dateCreated . } }
  bind(coalesce(?datePublished, ?dateCreated) as ?date)
  optional { graph ?a { ?obj a ?objType . } }
  optional { graph ?a { ?obj schema:keywords ?keyword . } }
}
group by ?np ?metadata ?obj ?date
order by desc(?date)""" .
}