sub:assertion {
  sub:get-latest-accepted-ds dct:description "This query returns the latest accepted nanopublications at the Biodiversity Data Journal (BDJ)." ;
    dct:license <http://www.apache.org/licenses/LICENSE-2.0> ;
    a <https://w3id.org/kpxl/grlc/grlc-query> ;
    rdfs:label "Get latest nanopublications accepted at BDJ" ;
    <https://w3id.org/kpxl/grlc/endpoint> <https://w3id.org/np/l/nanopub-query-1.1/repo/type/26df80496b38ffcad72b10e137bc78dbc6087e9eb171c09b10f2c9bf4240abc6> ;
    <https://w3id.org/kpxl/grlc/sparql> """prefix np: <http://www.nanopub.org/nschema#>
prefix npa: <http://purl.org/nanopub/admin/>
prefix npx: <http://purl.org/nanopub/x/>
prefix xsd: <http://www.w3.org/2001/XMLSchema#>
prefix dct: <http://purl.org/dc/terms/>
prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix bibo: <http://purl.org/ontology/bibo/>

select ?np ?label ?firstAuthor ?date where {

values ?pubkey { \"1162349fdeaf431e71ab55898cb2a425b971d466150c2aa5b3c1beb498045a37\" \"cfe248c38933693b1ddeb62e17976a4d2396b0c738af5356bfffbe559d1a3de0\" \"170211c91a70e67992d52c760de3f0052c8c7271bd3c225ef0347245e8517ff6\" }

  graph npa:graph {
    ?np dct:created ?date .
    ?np npa:hasValidSignatureForPublicKeyHash ?pubkey .
    ?np rdfs:label ?label .
    ?np np:hasPublicationInfo ?i .
    filter not exists { ?np npx:hasNanopubType npx:ExampleNanopub . }
    filter not exists { ?npx npx:invalidates ?np ; npa:hasValidSignatureForPublicKeyHash ?pubkey . }
  }
  graph ?i {
    ?np bibo:authorList ?authorList .
    ?authorList rdf:_1 ?firstAuthor .
  }

}
order by desc(?date)
limit 100""" .
}