sub:assertion {
  sub:get-all-fsr dct:description "The query returns all FAIR Supporting Resources (FSRs)." ;
    dct:license <http://www.apache.org/licenses/LICENSE-2.0> ;
    a <https://w3id.org/kpxl/grlc/grlc-query> ;
    rdfs:label "Get all FSRs" ;
    <https://w3id.org/kpxl/grlc/endpoint> <https://w3id.org/np/l/nanopub-query-1.1/repo/full> ;
    <https://w3id.org/kpxl/grlc/sparql> """prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix np: <http://www.nanopub.org/nschema#>
prefix npa: <http://purl.org/nanopub/admin/>
prefix npx: <http://purl.org/nanopub/x/>
prefix xsd: <http://www.w3.org/2001/XMLSchema#>
prefix dct: <http://purl.org/dc/terms/>
prefix fip: <https://w3id.org/fair/fip/terms/>
prefix search: <http://www.openrdf.org/contrib/lucenesail#>

select distinct ?thing ?label ?description (group_concat(distinct ?type; separator=\" \") as ?types) ?np ?date where {

  graph npa:graph {
    <https://w3id.org/np/RA27Uhopq4MHZziL2lKXX-wTb1jz4KVLbHaupxyAcCt9Y> npa:hasValidSignatureForPublicKey ?curators_np_pk .
    ?latest_curators_np npa:hasValidSignatureForPublicKey ?curators_np_pk .
    filter not exists { ?latest_curators_npx npx:invalidates ?latest_curators_np ; npa:hasValidSignatureForPublicKey ?curators_np_pk . }
    ?latest_curators_np np:hasAssertion ?latest_curators_assertion .
  }
  graph npa:networkGraph {
    ?latest_curators_np (npx:supersedes)* <https://w3id.org/np/RA27Uhopq4MHZziL2lKXX-wTb1jz4KVLbHaupxyAcCt9Y> .
    filter not exists { ?latest_curators_npxx npx:supersedes ?latest_curators_np }
  }
       
    graph npa:graph {
      ?np rdfs:label ?label ;
          npa:hasValidSignatureForPublicKey ?pubkey ;
          dct:created ?date .
      ?np npx:introduces|npx:describes ?thing .
      filter(str(?date) > \"2022\")
      filter exists { ?np npx:hasNanopubType ?fsr_type . values ?fsr_type { fip:FAIR-Enabling-Resource fip:FAIR-Supporting-Resource fip:Available-FAIR-Enabling-Resource } }
      filter not exists { ?np npx:hasNanopubType npx:ExampleNanopub . }
      ?np npx:hasNanopubType ?type .
      filter(?type != fip:FAIR-Enabling-Resource)
      filter(?type != fip:Available-FAIR-Enabling-Resource)
      filter(?type != fip:FAIR-Enabling-Resource-to-be-Developed)
      filter(?type != fip:FAIR-Supporting-Resource)
      filter(?type != fip:Available-FAIR-Supporting-Resource)
      filter(?type != fip:FAIR-Supporting-Resource-to-be-Developed)
      filter not exists { ?npx npx:invalidates ?np ; npa:hasValidSignatureForPublicKey ?pubkey . }
      ?np np:hasAssertion ?a .
    }

    graph ?a {
      ?thing rdfs:comment ?description .
    }

    filter not exists {
      graph npa:graph {
        ?disapproval_np npx:hasNanopubType <http://purl.org/nanopub/x/disapprovesOf> .
        ?disapproval_np np:hasAssertion ?da ;
          npa:hasValidSignatureForPublicKey ?dpubkey .
        filter not exists { ?disapproval_npx npx:invalidates ?disapproval_np ; npa:hasValidSignatureForPublicKey ?dpubkey . }
      }
      graph ?latest_curators_assertion {
        ?qpubkeys npx:hasPublicKey ?dpubkey .
      }
      graph ?da {
        ?disapprover npx:disapprovesOf ?np .
      }
    }

} group by ?np ?thing ?description ?label ?date order by ?label""" .
}