sub:assertion {
  sub:get-weekly-active-human-user-count dct:description "Returns the number of active human users (with ORCID) per week (Mon-Sun)." ;
    dct:license <http://www.apache.org/licenses/LICENSE-2.0> ;
    a <https://w3id.org/kpxl/grlc/grlc-query> ;
    rdfs:label "Get weekly active human user count" ;
    <https://w3id.org/kpxl/grlc/endpoint> <https://w3id.org/np/l/nanopub-query-1.1/repo/full> ;
    <https://w3id.org/kpxl/grlc/sparql> """prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix np: <http://www.nanopub.org/nschema#>
prefix npa: <http://purl.org/nanopub/admin/>
prefix npx: <http://purl.org/nanopub/x/>
prefix xsd: <http://www.w3.org/2001/XMLSchema#>
prefix dct: <http://purl.org/dc/terms/>
prefix prov: <http://www.w3.org/ns/prov#>
prefix foaf: <http://xmlns.com/foaf/0.1/>

select ?week (substr(str(min(?date)), 0, 11) as ?firstday) (count(distinct ?userid) as ?usercount) where {
  graph npa:graph {
    ?np npa:hasValidSignatureForPublicKey ?pubkey .
    ?np npx:signedBy ?userid .
    ?np dct:created ?date .
  }
  filter(strstarts(str(?userid), \"https://orcid.org/\"))
  bind(if(month(?date) <= 2, year(?date) - 1, year(?date)) as ?y)
  bind(if(month(?date) <= 2, month(?date) + 9, month(?date) - 3) as ?m)
  bind(365*?y + xsd:integer(?y/4) - xsd:integer(?y/100) + xsd:integer(?y/400) + xsd:integer((153*?m + 2)/5) + day(?date) as ?daynum)
  bind(?daynum + 1 - xsd:integer((?daynum + 1) / 7) * 7 as ?dow)
  bind(xsd:integer((?daynum - ?dow) / 7) as ?week)
}
group by ?week
order by desc(?week)""" .
}