sub:assertion {
  sub:find-fdos-by-ref dct:description "This query returns the FDOs whose records refer to the given ID." ;
    dct:license <http://www.apache.org/licenses/LICENSE-2.0> ;
    a <https://w3id.org/kpxl/grlc/grlc-query> ;
    rdfs:label "Get FDOs by reference" ;
    <https://w3id.org/kpxl/grlc/endpoint> <https://w3id.org/np/l/nanopub-query-1.1/repo/type/f82fa5e467e6ba40c5d14402c3590f2ad8ed9a13e982133ab26ef1a889b34ebd> ;
    <https://w3id.org/kpxl/grlc/sparql> """prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix dct: <http://purl.org/dc/terms/>
prefix np: <http://www.nanopub.org/nschema#>
prefix npa: <http://purl.org/nanopub/admin/>
prefix npx: <http://purl.org/nanopub/x/>

select distinct ?fdo ?np ?label ?creator ?date where {
  bind(if(strstarts(?_refid, \"https://\") || strstarts(?_refid, \"http://\"), iri(?_refid), iri(concat(\"https://hdl.handle.net/\", str(?_refid)))) as ?ref)
  graph npa:graph {
    ?np npa:hasValidSignatureForPublicKey ?pubkey .
    filter not exists { ?npx npx:invalidates ?np ; npa:hasValidSignatureForPublicKey ?pubkey . }
    ?np dct:created ?date .
    ?np npx:hasNanopubType <https://w3id.org/fdof/ontology#FAIRDigitalObject> .
    ?np npx:introduces ?fdo .
    ?np np:hasAssertion ?a .
    optional { ?np rdfs:label ?label }
    optional { ?np npx:signedBy ?creator }
  }
  optional { graph ?a {
    ?subj ?ref ?obj .
    bind(true as ?inpred)
  } }
  optional { graph ?a {
    ?subj ?pred ?ref .
    bind(true as ?inobj)
  } }
  filter(?inpred || ?inobj)
} order by desc(?date)""" .
}