sub:assertion {
  sub:get-space-member-roles dct:description "This query returns the roles of a given Space." ;
    dct:license <http://www.apache.org/licenses/LICENSE-2.0> ;
    a <https://w3id.org/kpxl/grlc/grlc-query> ;
    rdfs:label "Get Space member roles" ;
    <https://w3id.org/kpxl/grlc/endpoint> <https://w3id.org/np/l/nanopub-query-1.1/repo/type/9ed830412329d775e56a89d7548b4579d01d2188252bc25cbdd3fe70696808c1> ;
    <https://w3id.org/kpxl/grlc/sparql> """prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix dct: <http://purl.org/dc/terms/>
prefix owl: <http://www.w3.org/2002/07/owl#>
prefix np: <http://www.nanopub.org/nschema#>
prefix npa: <http://purl.org/nanopub/admin/>
prefix npx: <http://purl.org/nanopub/x/>
prefix gen: <https://w3id.org/kpxl/gen/terms/>

select ?role ?roleName ?isInverse (group_concat(?eq; separator=' ') as ?equivalent) (group_concat(?inv; separator=' ') as ?inverse) ?np ?pubkey ?date where {
  graph npa:graph {
    ?np npa:hasValidSignatureForPublicKeyHash ?pubkey .
    filter not exists { ?npx npx:invalidates ?np ; npa:hasValidSignatureForPublicKeyHash ?pubkey . }
    ?np dct:created ?date .
    ?np np:hasAssertion ?a .
  }
  graph ?a {
    ?role a gen:SpaceMemberRole .
    ?role dct:title ?roleName .
    ?role gen:isRoleOf ?_space_iri .
    bind( exists { ?role a gen:InverseSpaceMemberRole } as ?isInverse )
    optional { ?role owl:equivalentProperty ?eq }
    optional { ?role owl:inverseOf ?inv }
  }
} group by ?role ?roleName ?isInverse  ?np ?pubkey ?date
order by desc(?date)""" .
}