sub:assertion {
  sub:get-all-cs dct:description "This query returns all case studies" ;
    dct:license <http://www.apache.org/licenses/LICENSE-2.0> ;
    a <https://w3id.org/kpxl/grlc/grlc-query> ;
    rdfs:label "Get case studies" ;
    <https://w3id.org/kpxl/grlc/endpoint> <https://w3id.org/np/l/nanopub-query-1.1/repo/full> ;
    <https://w3id.org/kpxl/grlc/sparql> """PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX np: <http://www.nanopub.org/nschema#>
PREFIX npa: <http://purl.org/nanopub/admin/>
PREFIX npx: <http://purl.org/nanopub/x/>
PREFIX fff: <https://w3id.org/fff/req/>

SELECT DISTINCT ?np ?date ?label ?caseStudy
WHERE {

  ## Info about this repo
  npa:thisRepo ?repoPred ?repoObj .

  ## Search for valid nanopublications
  GRAPH npa:graph {
    ?np npa:hasValidSignatureForPublicKey ?pubkey .
    FILTER NOT EXISTS {
      ?invalid npx:invalidates ?np ;
               npa:hasValidSignatureForPublicKey ?pubkey .
    }
    ?np dct:created ?date .
    ?np np:hasAssertion ?a .
    OPTIONAL { ?np rdfs:label ?label }
  }

  ## Look inside the assertion graph
  GRAPH ?a {
    ?caseStudy a fff:Case-Study .
  }
}
ORDER BY DESC(?date)""" .
}