sub:assertion {
  sub:get-weekly-new-user-count dct:description "Returns the number of human users who published their first introduction nanopub per week (Mon-Sun)." ;
    dct:license <http://www.apache.org/licenses/LICENSE-2.0> ;
    a <https://w3id.org/kpxl/grlc/grlc-query> ;
    rdfs:label "Get weekly new user count" ;
    <https://w3id.org/kpxl/grlc/endpoint> <https://w3id.org/np/l/nanopub-query-1.1/repo/full> ;
    <https://w3id.org/kpxl/grlc/sparql> """prefix np: <http://www.nanopub.org/nschema#>
prefix npa: <http://purl.org/nanopub/admin/>
prefix npx: <http://purl.org/nanopub/x/>
prefix xsd: <http://www.w3.org/2001/XMLSchema#>
prefix dct: <http://purl.org/dc/terms/>

select ?week (substr(str(min(?firstdate)), 0, 11) as ?firstday) (count(distinct ?userid) as ?newusercount) where {
  {
    select ?userid (min(?date) as ?firstdate) where {
      graph npa:graph {
        ?np npa:hasValidSignatureForPublicKey ?pubkey .
        ?np npx:signedBy ?userid .
        ?np npx:hasNanopubType npx:declaredBy .
        ?np dct:created ?date .
      }
      filter(strstarts(str(?userid), \"https://orcid.org/\"))
      filter(?userid != <https://orcid.org/0000-0000-0000-0000>)
      filter(?userid != <https://orcid.org/1234-1234-1234-1234>)
    }
    group by ?userid
  }

  bind(if(month(?firstdate) <= 2, year(?firstdate) - 1, year(?firstdate)) as ?y)
  bind(if(month(?firstdate) <= 2, month(?firstdate) + 9, month(?firstdate) - 3) as ?m)
  bind(365*?y + xsd:integer(?y/4) - xsd:integer(?y/100) + xsd:integer(?y/400) + xsd:integer((153*?m + 2)/5) + day(?firstdate) as ?daynum)
  bind(?daynum + 1 - xsd:integer((?daynum + 1) / 7) * 7 as ?dow)
  bind(xsd:integer((?daynum - ?dow) / 7) as ?week)
}
group by ?week
order by desc(?week)""" .
}