sub:assertion {
  sub:get-RORaffiliated-datasets dct:description "This query returns all datasets affiliated with a ROR-registered research organization." ;
    dct:license <http://www.apache.org/licenses/LICENSE-2.0> ;
    a <https://w3id.org/kpxl/grlc/grlc-query> ;
    rdfs:label "Get ROR-affiliated datasets" ;
    <https://w3id.org/kpxl/grlc/endpoint> <https://w3id.org/np/l/nanopub-query-1.1/repo/full> ;
    <https://w3id.org/kpxl/grlc/sparql> """PREFIX prov: <http://www.w3.org/ns/prov#>
PREFIX schema: <https://schema.org/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX np: <http://www.nanopub.org/nschema#>
PREFIX npa: <http://purl.org/nanopub/admin/>
PREFIX npx: <http://purl.org/nanopub/x/>

SELECT DISTINCT ?dataset ?label ?repository ?ror
WHERE {
  GRAPH npa:graph {
    ?np npa:hasValidSignatureForPublicKey ?pubkey .
    FILTER NOT EXISTS {
      ?npx npx:invalidates ?np ;
           npa:hasValidSignatureForPublicKey ?pubkey .
    }
    ?np dct:created ?date .
    ?np np:hasAssertion ?a .
    ?np np:hasProvenance ?p .
  }

  GRAPH ?a {
    ?dataset a <http://purl.org/dc/dcmitype/Dataset> .
    OPTIONAL { ?dataset dct:title ?label . }
    OPTIONAL { ?dataset schema:maintainer ?repository . }
  }

  GRAPH ?p {
    ?a prov:wasAttributedTo ?ror .
    FILTER(STRSTARTS(STR(?ror), \"https://ror.org/\"))
  }
}""" .
}