sub:assertion {
  sub:list_nonqualifed_fsr dct:description "List all non-qualified FAIR Enabling/Supporting Resources." ;
    dct:license <http://www.apache.org/licenses/LICENSE-2.0> ;
    a <https://w3id.org/kpxl/grlc/grlc-query> ;
    rdfs:label "List non-qualified FERs/FSRs" ;
    <https://w3id.org/kpxl/grlc/endpoint> <https://w3id.org/np/l/nanopub-query-1.1/repo/empty> ;
    <https://w3id.org/kpxl/grlc/sparql> """prefix np: <http://www.nanopub.org/nschema#>
prefix npa: <http://purl.org/nanopub/admin/>
prefix npx: <http://purl.org/nanopub/x/>
prefix xsd: <http://www.w3.org/2001/XMLSchema#>
prefix dct: <http://purl.org/dc/terms/>
prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>

select distinct ?np ?label (group_concat(distinct ?typelabel; separator = \", \") as ?types) ?date where {

values ?service {
  <https://w3id.org/np/l/nanopub-query-1.1/repo/type/3ef5b11551ebc44e34f4bca614b387204447656ce195314532769ca7b20143fe>
  <https://w3id.org/np/l/nanopub-query-1.1/repo/type/070fa9a0f87a189bc2eb9d4c1a14f68f11538cc2229b9f4fd6ac026a3d2ce570>
}
service ?service {
  graph npa:graph {
    ?np npa:hasValidSignatureForPublicKey ?pubkey .
    filter not exists { ?npx npx:invalidates ?np ; npa:hasValidSignatureForPublicKey ?pubkey . }
    filter not exists { ?np npx:hasNanopubType npx:ExampleNanopub . }
    ?np dct:created ?date .
    filter(str(?date) > \"2022\")
    ?np np:hasAssertion ?a .
  }
  graph ?a {
    #?thing a <https://w3id.org/fair/fip/terms/FAIR-Supporting-Resource> .
    ?thing a ?type .
    ?thing rdfs:label ?labelx .
  }
}

filter( ?type != <https://w3id.org/fair/fip/terms/FAIR-Supporting-Resource> )
filter( ?type != <https://w3id.org/fair/fip/terms/Available-FAIR-Supporting-Resource> )
filter( ?type != <https://w3id.org/fair/fip/terms/FAIR-Supporting-Resource-to-be-Developed> )
filter( ?type != <https://w3id.org/fair/fip/terms/FAIR-Enabling-Resource> )
filter( ?type != <https://w3id.org/fair/fip/terms/Available-FAIR-Enabling-Resource> )
filter( ?type != <https://w3id.org/fair/fip/terms/FAIR-Enabling-Resource-to-be-Developed> )
bind(replace(str(?type), '^.*/([^/]+)$', '$1') as ?typelabel)
bind(str(?labelx) as ?label)

optional { select ?np ?disapproval { service <https://w3id.org/np/l/nanopub-query-1.1/repo/type/39692876d0a7881c82e9a2cb6dc8859fb16fa69fb41cea2ace2f8fa70bc52aed> {
  graph npa:graph {
    ?disapproval npa:hasValidSignatureForPublicKey ?dpubkey .
    ?disapproval np:hasAssertion ?da .
    filter not exists { ?disapprovalx npx:invalidates ?disapproval ; npa:hasValidSignatureForPublicKey ?dpubkey . }
  }
  graph <https://w3id.org/np/RAkVk6aKWsmgcuKtPA7OSp2h-GbDfx8xrz_kJAAgY8Xa4#assertion> {
    ?dpubkeys npx:hasPublicKey ?dpubkey .
  }
  graph ?da {
    ?dsomebody npx:disapprovesOf ?np .
  }
} } }
filter(!bound(?disapproval))

 
optional { select ?np ?qualification { service <https://w3id.org/np/l/nanopub-query-1.1/repo/type/cd51a3ac3e109fd12aacd5a324e14ebff644ce209c916e4250a3f50c2ddf0051> {
  graph npa:graph {
    ?qualification npa:hasValidSignatureForPublicKey ?qpubkey .
    ?qualification np:hasAssertion ?qa .
    filter not exists { ?qualificationx npx:invalidates ?qualification ; npa:hasValidSignatureForPublicKey ?qpubkey . }
  }
  graph <https://w3id.org/np/RAkVk6aKWsmgcuKtPA7OSp2h-GbDfx8xrz_kJAAgY8Xa4#assertion> {
    ?qpubkeys npx:hasPublicKey ?qpubkey .
  }
  graph ?qa {
    ?qsomebody npx:qualifies ?np .
  }
} } }
filter(!bound(?qualification))

}
group by ?np ?label ?date
order by desc(?date)""" .
}